Использование/Обновление реляционных выпадающих списков

Предположение: у вас есть документ Word с двумя раскрывающимися элементами управления содержимым. Для обоих тегов задано имя: ccType и ccSelection.

В модуле классаThisDocument вы вводите следующий код:

Option Explicit

Private Sub Document_ContentControlOnExit(ByVal ContentControl As ContentControl, Cancel As Boolean)
If ContentControl.Tag = "ccType" Then
    fillccSelection ContentControl.Range.Text
End If
End Sub

Private Sub fillccSelection(valueType As String)

Dim cc As ContentControl
Set cc = ThisDocument.SelectContentControlsByTag("ccSelection")(1)

If cc.Title <> valueType Then
    With cc
        .Title = valueType  'set title to current type so that we now if coming here next time
        .Range.Text = vbNullString  'clear content as it has to change with new values
        With .DropdownListEntries
            .Clear
            Select Case valueType
                Case "Numbers"
                    cc.SetPlaceholderText Text:="Please select a number"
                    .Add "1"
                    .Add "2"
                    .Add "3"

                Case "Letters"
                    cc.SetPlaceholderText Text:="Please select a letter"
                    .Add "A"
                    .Add "B"
                    .Add "C"
            End Select
        End With
    End With
End If
End Sub

Всякий раз, когда вы изменяете значение первого элемента управления содержимым (ccType) и выходите из него, запускается ContentControlOnExit.

Если вы "оставили" ccType (а не ccSelection), fillccSelection вызывается путем передачи значения, выбранного в ccType.

Если этот тип еще не задан для выбора CCS, раскрывающиеся записи устанавливаются в соответствии с выбранным типом.